Привет, незнакомец!

Похоже, вы здесь новенький. Чтобы принять участие, нажмите одну из кнопок ниже!

Смарт-контракт на Solidity: Часть 6 — токен ERC20 — рефакторинг

отредактировано December 2017 Раздел: Смарт Контракты

Серия уроков были взяты с сайте inaword.ru

На прошлом уроке мы с Вами написали свой первый токен ERC20. Код мы писали на ходу и поместили практически все функционал в один контракт. Для скорости изучения это было хорошо. Но теперь нужно научиться писать контракты как взрослые. Вот некоторые рекомендации по написанию хорошего (хорошего) контракта:

  1. Не изобретать велосипед, а пытаться брать уже готовые решения и изменять их под себя. Если задача популярна, тогда к Вам уже наступили на все грабли и нашли решение. Токенов ERC20 уже написано достаточно много. И на GitHub можно всегда посмотреть код. Например, вот этот.
  2. Использовать устоявшиеся шаблоны проектирования. Такие шаблоны построены на основе опыта решения задач другими программистами. Так контракт токена ERC20 обычно имеет структуру подражания, не существенно отличается от проекта к проекту.
  3. Стараться выделять код, который можно переиспользовать. Мы с Вами на прошлых уроках выделили контракт Ownable. И уже убедились что не зря. Мы его использовали в контракте-визитке и в нашем токене.
  4. Выделять стандарты в виде интерфейсов. Одна из причин такого подхода - в нашем коде невозможно понять какие из функций относятся к стандарту, а какие нет.
    Давайте посмотрим на структуру, которая часто встречается, подражания токена ERC20.

Название контрактов может отличаться от проекта к проекту, но мы будем ориентироваться на этот [репозиторий] (https://github.com/OpenZeppelin/zeppelin-solidity/tree/master/contracts/token "репозиторий"). Такая же структура, но с названием контрактов.

На прошлом уроке мы говорили только о стандарте ERC20. А тут появился какой-то [ERC179] (https://github.com/ethereum/EIPs/issues/179 "ERC179»). Здесь все просто. Как оказалось не всем нужна часть, которая отвечает за представление разрешений на снятие средств. Поэтому все функции, не относящиеся к механизму предоставления разрешений, вынесли в ERC179. Поэтому стандарт ERC20 это тот же [ERC179] (https://github.com/ethereum/EIPs/issues/179 "ERC179") только с дополнительными функциями и событиями.

Контракты StandartToken и BasicToken - это частично реализации стандартов.

Поскольку наш токен полностью соответствует ERC20, то мы будем наследоваться от контракта StandartToken.

Кроме задач ERC20 в нашем токене есть еще функции, отвечающие за эмиссию новых монет. Это тоже широко-используемого шаблона. Контракты, которые могут выпускать новые монеты, как правило, называют Mintable. А поскольку выпускать новые монеты могут только владелец контракта, то Mintable наследуется от Ownable.

А теперь давайте вспомним, что в нашем контракте были проверки на отрицательный (отрицательный) баланс, проверки на наполнение. В будущем нам могут пригодится проверки деления на ноль и так далее. Все эти проверки в случае неудачи прерывают выполнение функции. Они используются очень часто, поэтому принято их выделять в отдельную библиотеку защищенных математических операций - SafeMath. В большинстве проектов она скопирована один в один.

С учетом всего вышесказанного структура контрактов нашего токена теперь выглядит так:

Важно понимать, что от библиотеки не наследуется. Их "используют", то есть подключают к контракту. Например, для SafeMath это выглядит так:

using SafeMath for uint256;

Возьмем готовый код стандартных шаблонов с репозитория ZeppelinSolidity и перепишем наш токен:

  1. [ERC20Basic] (https://github.com/OpenZeppelin/zeppelin-solidity/blob/master/contracts/token/ERC20Basic.sol "ERC20Basic») - интерфейс ERC179, то есть ERC20 без механизма предоставления разрешений
  2. [ERC20] (https://github.com/OpenZeppelin/zeppelin-solidity/blob/master/contracts/token/ERC20.sol "ERC20») - интерфейс ERC20
  3. [BasicToken] (https://github.com/OpenZeppelin/zeppelin-solidity/blob/master/contracts/token/BasicToken.sol "BasicToken») - абстрактная реализация ERC179
  4. [StandartToken] (https://github.com/OpenZeppelin/zeppelin-solidity/blob/master/contracts/token/StandardToken.sol "StandartToken») - абстрактная реализация ERC20
  5. [Ownable] (https://github.com/OpenZeppelin/zeppelin-solidity/blob/master/contracts/ownership/Ownable.sol "Ownable») - позволяет ограничивать доступ к функциям всем кроме владельца контракта
  6. [SafeMath] (https://github.com/OpenZeppelin/zeppelin-solidity/blob/master/contracts/math/SafeMath.sol "SafeMath») - библиотека безопасных математических операций. В случае проблем с исполнением операций, работа функции прерывается
  7. [MintableToken] (https://github.com/OpenZeppelin/zeppelin-solidity/blob/master/contracts/token/MintableToken.sol "MintableToken») - предоставляет возможность выпуска новых монет. Если выпуск новых монет больше не нужен, то вызывается finishMinting (в ICO вызывается, как правило, после окончания распродажи монет). Возобновить выпуск монет больше нельзя будет. Конечно можно было бы дописать функцию, которая позволяет дополнительную эмиссию монет. Но шаблон, скорее всего, часто используется в ICO. В случае дополнительной эмиссии, после ICO цена монеты может размываться. А это плохо для покупателей нашей монеты. Поэтому если покупатель видит, что по окончании ICO не будете иметь физическую возможность выпускать новые монеты, то доверие к нам повысится.

А теперь посмотрите сколько строк кода мы должны были бы написать с нуля, если бы мы сразу использовали готовые решения:

pragma solidity ^0.4.13;

contract SimpleTokenCoin is MintableToken {

    string public constant name = "Simple Coint Token";

    string public constant symbol = "SCT";

    uint32 public constant decimals = 18;

}

Все остальное мы бы просто скопировали. А вот полный код:

pragma solidity ^0.4.13;

/**
 * @title ERC20Basic
 * @dev Simpler version of ERC20 interface
 * @dev see https://github.com/ethereum/EIPs/issues/179
 */
contract ERC20Basic {
  uint256 public totalSupply;
  function balanceOf(address who) constant returns (uint256);
  function transfer(address to, uint256 value) returns (bool);
  event Transfer(address indexed from, address indexed to, uint256 value);
}

/**
 * @title ERC20 interface
 * @dev see https://github.com/ethereum/EIPs/issues/20
 */
contract ERC20 is ERC20Basic {
  function allowance(address owner, address spender) constant returns (uint256);
  function transferFrom(address from, address to, uint256 value) returns (bool);
  function approve(address spender, uint256 value) returns (bool);
  event Approval(address indexed owner, address indexed spender, uint256 value);
}

/**
 * @title SafeMath
 * @dev Math operations with safety checks that throw on error
 */
library SafeMath {

  function mul(uint256 a, uint256 b) internal constant returns (uint256) {
    uint256 c = a * b;
    assert(a == 0 || c / a == b);
    return c;
  }

  function div(uint256 a, uint256 b) internal constant returns (uint256) {
    // assert(b > 0); // Solidity automatically throws when dividing by 0
    uint256 c = a / b;
    // assert(a == b * c + a % b); // There is no case in which this doesn't hold
    return c;
  }

  function sub(uint256 a, uint256 b) internal constant returns (uint256) {
    assert(b <= a);
    return a - b;
  }

  function add(uint256 a, uint256 b) internal constant returns (uint256) {
    uint256 c = a + b;
    assert(c >= a);
    return c;
  }

}

/**
 * @title Basic token
 * @dev Basic version of StandardToken, with no allowances. 
 */
contract BasicToken is ERC20Basic {

  using SafeMath for uint256;

  mapping(address => uint256) balances;

  /**
  * @dev transfer token for a specified address
  * @param _to The address to transfer to.
  * @param _value The amount to be transferred.
  */
  function transfer(address _to, uint256 _value) returns (bool) {
    balances[msg.sender] = balances[msg.sender].sub(_value);
    balances[_to] = balances[_to].add(_value);
    Transfer(msg.sender, _to, _value);
    return true;
  }

  /**
  * @dev Gets the balance of the specified address.
  * @param _owner The address to query the the balance of. 
  * @return An uint256 representing the amount owned by the passed address.
  */
  function balanceOf(address _owner) constant returns (uint256 balance) {
    return balances[_owner];
  }

}

/**
 * @title Standard ERC20 token
 *
 * @dev Implementation of the basic standard token.
 * @dev https://github.com/ethereum/EIPs/issues/20
 * @dev Based on code by FirstBlood: https://github.com/Firstbloodio/token/blob/master/smart_contract/FirstBloodToken.sol
 */
contract StandardToken is ERC20, BasicToken {

  mapping (address => mapping (address => uint256)) allowed;

  /**
   * @dev Transfer tokens from one address to another
   * @param _from address The address which you want to send tokens from
   * @param _to address The address which you want to transfer to
   * @param _value uint256 the amout of tokens to be transfered
   */
  function transferFrom(address _from, address _to, uint256 _value) returns (bool) {
    var _allowance = allowed[_from][msg.sender];

    // Check is not needed because sub(_allowance, _value) will already throw if this condition is not met
    // require (_value <= _allowance);

    balances[_to] = balances[_to].add(_value);
    balances[_from] = balances[_from].sub(_value);
    allowed[_from][msg.sender] = _allowance.sub(_value);
    Transfer(_from, _to, _value);
    return true;
  }

  /**
   * @dev Aprove the passed address to spend the specified amount of tokens on behalf of msg.sender.
   * @param _spender The address which will spend the funds.
   * @param _value The amount of tokens to be spent.
   */
  function approve(address _spender, uint256 _value) returns (bool) {

    // To change the approve amount you first have to reduce the addresses`
    //  allowance to zero by calling `approve(_spender, 0)` if it is not
    //  already 0 to mitigate the race condition described here:
    //  https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
    require((_value == 0) || (allowed[msg.sender][_spender] == 0));

    allowed[msg.sender][_spender] = _value;
    Approval(msg.sender, _spender, _value);
    return true;
  }

  /**
   * @dev Function to check the amount of tokens that an owner allowed to a spender.
   * @param _owner address The address which owns the funds.
   * @param _spender address The address which will spend the funds.
   * @return A uint256 specifing the amount of tokens still available for the spender.
   */
  function allowance(address _owner, address _spender) constant returns (uint256 remaining) {
    return allowed[_owner][_spender];
  }

}

/**
 * @title Ownable
 * @dev The Ownable contract has an owner address, and provides basic authorization control
 * functions, this simplifies the implementation of "user permissions".
 */
contract Ownable {

  address public owner;

  /**
   * @dev The Ownable constructor sets the original `owner` of the contract to the sender
   * account.
   */
  function Ownable() {
    owner = msg.sender;
  }

  /**
   * @dev Throws if called by any account other than the owner.
   */
  modifier onlyOwner() {
    require(msg.sender == owner);
    _;
  }

  /**
   * @dev Allows the current owner to transfer control of the contract to a newOwner.
   * @param newOwner The address to transfer ownership to.
   */
  function transferOwnership(address newOwner) onlyOwner {
    require(newOwner != address(0));      
    owner = newOwner;
  }

}

/**
 * @title Mintable token
 * @dev Simple ERC20 Token example, with mintable token creation
 * @dev Issue: * https://github.com/OpenZeppelin/zeppelin-solidity/issues/120
 * Based on code by TokenMarketNet: https://github.com/TokenMarketNet/ico/blob/master/contracts/MintableToken.sol
 */

contract MintableToken is StandardToken, Ownable {

  event Mint(address indexed to, uint256 amount);

  event MintFinished();

  bool public mintingFinished = false;

  modifier canMint() {
    require(!mintingFinished);
    _;
  }

  /**
   * @dev Function to mint tokens
   * @param _to The address that will recieve the minted tokens.
   * @param _amount The amount of tokens to mint.
   * @return A boolean that indicates if the operation was successful.
   */
  function mint(address _to, uint256 _amount) onlyOwner canMint returns (bool) {
    totalSupply = totalSupply.add(_amount);
    balances[_to] = balances[_to].add(_amount);
    Mint(_to, _amount);
    return true;
  }

  /**
   * @dev Function to stop minting new tokens.
   * @return True if the operation was successful.
   */
  function finishMinting() onlyOwner returns (bool) {
    mintingFinished = true;
    MintFinished();
    return true;
  }

}

contract SimpleTokenCoin is MintableToken {

    string public constant name = "Simple Coint Token";

    string public constant symbol = "SCT";

    uint32 public constant decimals = 18;

}

На этом уроке мы познакомились с общим подходом написания контрактов монеты [ERC20] (https://github.com/ethereum/EIPs/blob/master/EIPS/eip-20-token-standard.md "ERC20»). Научились использовать готовые решения, сильно упростило нам задачу и избавило от ошибок. Следует также отметить, что многие контракты написаны так, чтобы избежать уязвимости. Это может быть банальное перемещение двух строк кода, не всегда очевидно для начинающего.

Фактически из этих контрактов-кирпичиков мы можем собрать свой контракт на любой вкус с наименьшими усилиями. На самом деле таких устоявшихся шаблонов проектирования в solidity очень много. Далее мы познакомимся с некоторыми из них. А пока [здесь можно найти документацию по самым популярным шаблонам] (http://zeppelin-solidity.readthedocs.io/en/latest/index.html "здесь можно найти документацию по самым популярным шаблоны») от [OpenZeppelin] (https: // openzeppelin.org/ "OpenZeppelin»).

[Продолжение читать здесь.] (Http://ethereum.net.ua/discussion/22/smart-kontrakt-na-solidity-chast-7?new=1 "Продолжение читать здесь.")

Войдите или Зарегистрируйтесь чтобы комментировать.