Привет, незнакомец!

Похоже, вы здесь новенький. Чтобы принять участие, нажмите одну из кнопок ниже!

Смарт-контракт на Solidity: Часть 8 — ICO рефакторинг, выделение токенов для баунти и команды

отредактировано November 2017 Раздел: Смарт Контракты

Серия уроков были взяты с сайте inaword.ru

В прошлом уроке мы написали наш первый ICO смарт-контракт! В этом уроке мы продолжим изучать как написать смарт-контракт ICO на эфире. И сделаем следующие улучшения:
1. Установим границу сбора средств — hardcap. Т.е. если необходимая сумма в эфире собрана, то продажу токенов останавливаем. Конечно мы можем продолжить и дальше сбор. Но! Обычно цели на которые собираются средства прописываются в White Paper (информация о проекте для инвесторов). И на каждую цель указывается сумма, чтобы инвестор понимал куда пойдут его деньги. Если нет границы на сбор средств то это будет выглядеть подозрительно и у инвесторов возникнет много вопросов.
2. После окончания ICO выпустим долю токенов для своих нужд. В White Paper как правило прописывается доля токенов в процентном соотношении, которая остается у основателей. Часть из них может пойти основателям в карман, часть на оплату баунти-кампаний (пиар-кампании в соц.сетях, СМИ, блогах, форумах).

Итак, приступим.

Во первых вынесем код проверки дат ICO в модификатор (код контракта ICO можно посмотреть в конце предыдущего урока). Раньше проверка у нас была такой:

require(now > start && now < start + period*24*60*60);

А теперь будет как модификатор:

modifier saleIsOn() {
        require(now > start && now < start + period * 1 days);
        _;
}

Тут внимательный читатель заметит, что вместо умножения «246060» мы использовали «1 days». В solidty есть встроенные единицы измерения (ссылка на официальную документацию). Вот они:

  1. 1 == 1 seconds
  2. 1 minutes == 60 seconds
  3. 1 hours == 60 minutes
  4. 1 days == 24 hours
  5. 1 weeks == 7 days
  6. 1 years == 365 days

Соответственно при их использовании происходит пересчет в секунды. Есть тонкий момент. Если вы используете число с единицей измерения, например вот так:

uint time = 2 days;

то все будет работать нормально. Если же вы хотите умножить на переменную и запишите так

uint time = period * days;

То компилятор будет ругаться, поэтому необходимо использовать так:

uint time = period * 1 days;

В контракте ICO обычно полученный эфир не отсылают на адрес владельца контракта, а отсылают его на отдельный адрес. Это делается затем, что на отдельном адресе может быть как обычный аккаунт, так и контракт эскроу (специальный счет, управляемый доверенными лицами, в целях повышения доверия инвесторов — об этом мы поговорим в следующих уроках). В нашем случае мы будем задавать адрес простого аккаунта в конструкторе. Называться у нас он будет multisig.

address multisig;

Теперь добавим ограничение на сумму, которую нам нужно собрать. Если сумма собрана, то попытка пользователя купить токены будет отклоняться. Для начала введем переменную hardcap, которая будет хранить границу суммы которую нужно собрать.

uint hardcap;

Пока задавать значение не будем. Все это мы сделаем в конце в конструкторе контракта ICO.

Теперь напишем модификатор, который будет проверять условие по hardcap. Мы имеем верхнюю границу hardcap и адрес на который будут отправляться средства, а баланс аккаунта хранится в поле balance. Запишем наш модификатор

modifier isUnderHardCap() {
        require(multisig.balance <= hardcap);
        _;
}

Еще немного рефакторинга. Вынесем код из fallback (напоминаю — fallback функция вызывается у контракта, когда на него пересылают эфир) функции в отдельную функцию. Заменим условие начала распродажи на модификатор и добавим модификатор верхней границы средств.

    function createTokens() isUnderHardCap saleIsOn payable {
        multisig.transfer(msg.value);
        token.mint(msg.sender, msg.value);
    }

    function() external payable {
        createTokens();
    }

Для удобств введем коэффициент пересчета эфира в наши токены. Инициализировать его также будем в конструкторе.

uint rate;

Тогда наша функция createTokens немного изменится:

function createTokens() isUnderHardCap saleIsOn payable {
        multisig.transfer(msg.value);
        uint tokens = rate.mul(msg.value).div(1 ether);
        token.mint(msg.sender, tokens);
}

Мы используем операции div и mul из библиотеки безопасных математических операций SafeMath (см. урок 6), поэтому не забываем ее подключить.

using SafeMath for uint;

Обратите внимание что функция createTokens объявлена как payable, потому что принимаем эфир. Частая ошибка когда забывают указать payable!

Теперь давайте разберемся с выпуском токенов для наших нужд. Как мы уже отмечали ранее обычно в White Paper указывается какой процент токенов пойдет на распродажу, а какой останется для разработчиков и других нужд. Наш контракт заранее не выпускает токены, поэтому мы не можем заранее узнать сколько токенов будет выпущено. Поэтому рассчитывать токены себе мы будем в конце ICO. Мы напишем функцию finishMinting, которую самостоятельно будем вызывать в конце ICO. И она нам рассчитает и выпустит токены. Для этого укажем счет — restricted . А также процент токенов, который мы хотим получить — restricedPercent.

uint restrictedPercent;

address restricted;

Осталось написать нашу функцию для расчета:

function finishMinting() public onlyOwner {
    uint issuedTokenSupply = token.totalSupply();
    uint restrictedTokens = issuedTokenSupply.mul(restrictedPercent).div(100 - restrictedPercent);
    token.mint(restricted, restrictedTokens);
        token.finishMinting();
}

В ней мы берем у контракта токена количество всех выпущенных токенов, рассчитываем сколько нужно довыпустить нам restrictedTokens. Выпускаем их на счет restricted. А дальше вызываем finishMinting у контракта токена — эта функция запрещает выпускать новые токены (Содержится в шаблоне MintableToken см. урок 6). Обратите внимание что мы не забыли использовать модификатор onlyOwner (он определен в контракте Ownable), потому как наша функция должна вызываться только владельцем контракта! В противном случае завершить ICO сможет любой посторонний человек.
Настало время посмотреть как выглядить наш контракт распродажи после всех улучшений.

contract Crowdsale is Ownable {

    using SafeMath for uint;    

    address multisig;

    uint restrictedPercent;

    address restricted;

    SimpleTokenCoin public token = new SimpleTokenCoin();

    uint start;

    uint period;

    uint hardcap;

    uint rate;

    function Crowdsale() {
    // initialize all fields
    }

    modifier saleIsOn() {
        require(now > start && now < start + period * 1 days);
        _;
    }

    modifier isUnderHardCap() {
        require(multisig.balance <= hardcap);
        _;
    }

    function finishMinting() public onlyOwner {
    uint issuedTokenSupply = token.totalSupply();
    uint restrictedTokens = issuedTokenSupply.mul(restrictedPercent).div(100 - restrictedPercent);
    token.mint(restricted, restrictedTokens);
        token.finishMinting();
    }

    function createTokens() isUnderHardCap saleIsOn payable {
        multisig.transfer(msg.value);
        uint tokens = rate.mul(msg.value).div(1 ether);
        token.mint(msg.sender, tokens);
    }

    function() external payable {
        createTokens();
    }

}

Осталось только инициализировать поля в конструкторе, а для этого понадобится:

  1. Адрес куда будет перчислятся эфир — multisig. Пусть будет 0xEA15Adb66DC92a4BbCcC8Bf32fd25E2e86a2A770.
  2. Адрес куда будут перечисляться токены для наших нужд — restricted. Пусть будет — 0xb3eD172CC64839FB0C0Aa06aa129f402e994e7De.
  3. Процент токенов на наши нужды restrictedPercent пусть будет 40%.
  4. Время начала ICO — GMT в UNIX формате (см. урок 7) — start. Пусть будет как в 7-мом уроке — 18 июля 2017 года в 15 часов. В UNIX — 1500379200. Для тестирования не забывайте поменять дату на свою!
  5. Время проведения ICO в днях — period. У нас будет 28 дней.
  6. rate у нас будет — 100000000000000000000

После всего этого полный контракт со всеми шаблонами выглядит так:

pragma solidity ^0.4.13;

/**
 * @title ERC20Basic
 * @dev Simpler version of ERC20 interface
 * @dev see https://github.com/ethereum/EIPs/issues/179
 */
contract ERC20Basic {
  uint256 public totalSupply;
  function balanceOf(address who) constant returns (uint256);
  function transfer(address to, uint256 value) returns (bool);
  event Transfer(address indexed from, address indexed to, uint256 value);
}

/**
 * @title ERC20 interface
 * @dev see https://github.com/ethereum/EIPs/issues/20
 */
contract ERC20 is ERC20Basic {
  function allowance(address owner, address spender) constant returns (uint256);
  function transferFrom(address from, address to, uint256 value) returns (bool);
  function approve(address spender, uint256 value) returns (bool);
  event Approval(address indexed owner, address indexed spender, uint256 value);
}

/**
 * @title SafeMath
 * @dev Math operations with safety checks that throw on error
 */
library SafeMath {

  function mul(uint256 a, uint256 b) internal constant returns (uint256) {
    uint256 c = a * b;
    assert(a == 0 || c / a == b);
    return c;
  }

  function div(uint256 a, uint256 b) internal constant returns (uint256) {
    // assert(b > 0); // Solidity automatically throws when dividing by 0
    uint256 c = a / b;
    // assert(a == b * c + a % b); // There is no case in which this doesn't hold
    return c;
  }

  function sub(uint256 a, uint256 b) internal constant returns (uint256) {
    assert(b <= a);
    return a - b;
  }

  function add(uint256 a, uint256 b) internal constant returns (uint256) {
    uint256 c = a + b;
    assert(c >= a);
    return c;
  }

}

/**
 * @title Basic token
 * @dev Basic version of StandardToken, with no allowances. 
 */
contract BasicToken is ERC20Basic {

  using SafeMath for uint256;

  mapping(address => uint256) balances;

  /**
  * @dev transfer token for a specified address
  * @param _to The address to transfer to.
  * @param _value The amount to be transferred.
  */
  function transfer(address _to, uint256 _value) returns (bool) {
    balances[msg.sender] = balances[msg.sender].sub(_value);
    balances[_to] = balances[_to].add(_value);
    Transfer(msg.sender, _to, _value);
    return true;
  }

  /**
  * @dev Gets the balance of the specified address.
  * @param _owner The address to query the the balance of. 
  * @return An uint256 representing the amount owned by the passed address.
  */
  function balanceOf(address _owner) constant returns (uint256 balance) {
    return balances[_owner];
  }

}

/**
 * @title Standard ERC20 token
 *
 * @dev Implementation of the basic standard token.
 * @dev https://github.com/ethereum/EIPs/issues/20
 * @dev Based on code by FirstBlood: https://github.com/Firstbloodio/token/blob/master/smart_contract/FirstBloodToken.sol
 */
contract StandardToken is ERC20, BasicToken {

  mapping (address => mapping (address => uint256)) allowed;

  /**
   * @dev Transfer tokens from one address to another
   * @param _from address The address which you want to send tokens from
   * @param _to address The address which you want to transfer to
   * @param _value uint256 the amout of tokens to be transfered
   */
  function transferFrom(address _from, address _to, uint256 _value) returns (bool) {
    var _allowance = allowed[_from][msg.sender];

    // Check is not needed because sub(_allowance, _value) will already throw if this condition is not met
    // require (_value <= _allowance);

    balances[_to] = balances[_to].add(_value);
    balances[_from] = balances[_from].sub(_value);
    allowed[_from][msg.sender] = _allowance.sub(_value);
    Transfer(_from, _to, _value);
    return true;
  }

  /**
   * @dev Aprove the passed address to spend the specified amount of tokens on behalf of msg.sender.
   * @param _spender The address which will spend the funds.
   * @param _value The amount of tokens to be spent.
   */
  function approve(address _spender, uint256 _value) returns (bool) {

    // To change the approve amount you first have to reduce the addresses`
    //  allowance to zero by calling `approve(_spender, 0)` if it is not
    //  already 0 to mitigate the race condition described here:
    //  https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
    require((_value == 0) || (allowed[msg.sender][_spender] == 0));

    allowed[msg.sender][_spender] = _value;
    Approval(msg.sender, _spender, _value);
    return true;
  }

  /**
   * @dev Function to check the amount of tokens that an owner allowed to a spender.
   * @param _owner address The address which owns the funds.
   * @param _spender address The address which will spend the funds.
   * @return A uint256 specifing the amount of tokens still available for the spender.
   */
  function allowance(address _owner, address _spender) constant returns (uint256 remaining) {
    return allowed[_owner][_spender];
  }

}

/**
 * @title Ownable
 * @dev The Ownable contract has an owner address, and provides basic authorization control
 * functions, this simplifies the implementation of "user permissions".
 */
contract Ownable {

  address public owner;

  /**
   * @dev The Ownable constructor sets the original `owner` of the contract to the sender
   * account.
   */
  function Ownable() {
    owner = msg.sender;
  }

  /**
   * @dev Throws if called by any account other than the owner.
   */
  modifier onlyOwner() {
    require(msg.sender == owner);
    _;
  }

  /**
   * @dev Allows the current owner to transfer control of the contract to a newOwner.
   * @param newOwner The address to transfer ownership to.
   */
  function transferOwnership(address newOwner) onlyOwner {
    require(newOwner != address(0));      
    owner = newOwner;
  }

}

/**
 * @title Mintable token
 * @dev Simple ERC20 Token example, with mintable token creation
 * @dev Issue: * https://github.com/OpenZeppelin/zeppelin-solidity/issues/120
 * Based on code by TokenMarketNet: https://github.com/TokenMarketNet/ico/blob/master/contracts/MintableToken.sol
 */

contract MintableToken is StandardToken, Ownable {

  event Mint(address indexed to, uint256 amount);

  event MintFinished();

  bool public mintingFinished = false;

  modifier canMint() {
    require(!mintingFinished);
    _;
  }

  /**
   * @dev Function to mint tokens
   * @param _to The address that will recieve the minted tokens.
   * @param _amount The amount of tokens to mint.
   * @return A boolean that indicates if the operation was successful.
   */
  function mint(address _to, uint256 _amount) onlyOwner canMint returns (bool) {
    totalSupply = totalSupply.add(_amount);
    balances[_to] = balances[_to].add(_amount);
    Mint(_to, _amount);
    return true;
  }

  /**
   * @dev Function to stop minting new tokens.
   * @return True if the operation was successful.
   */
  function finishMinting() onlyOwner returns (bool) {
    mintingFinished = true;
    MintFinished();
    return true;
  }

}

contract SimpleTokenCoin is MintableToken {

    string public constant name = "Simple Coint Token";

    string public constant symbol = "SCT";

    uint32 public constant decimals = 18;

}


contract Crowdsale is Ownable {

    using SafeMath for uint;

    address multisig;

    uint restrictedPercent;

    address restricted;

    SimpleTokenCoin public token = new SimpleTokenCoin();

    uint start;

    uint period;

    uint hardcap;

    uint rate;

    function Crowdsale() {
        multisig = 0xEA15Adb66DC92a4BbCcC8Bf32fd25E2e86a2A770;
        restricted = 0xb3eD172CC64839FB0C0Aa06aa129f402e994e7De;
        restrictedPercent = 40;
        rate = 100000000000000000000;
        start = 1500379200;
        period = 28;
        hardcap = 10000000000000000000000;
    }

    modifier saleIsOn() {
        require(now > start && now < start + period * 1 days);
        _;
    }

    modifier isUnderHardCap() {
        require(multisig.balance <= hardcap);
        _;
    }

    function finishMinting() public onlyOwner {
        uint issuedTokenSupply = token.totalSupply();
        uint restrictedTokens = issuedTokenSupply.mul(restrictedPercent).div(100 - restrictedPercent);
        token.mint(restricted, restrictedTokens);
        token.finishMinting();
    }

    function createTokens() isUnderHardCap saleIsOn payable {
        multisig.transfer(msg.value);
        uint tokens = rate.mul(msg.value).div(1 ether);
        token.mint(msg.sender, tokens);
    }

    function() external payable {
        createTokens();
    }

}

В этом уроке мы научились выпускать дополнительные токены по окончанию ICO. А также установили границу по сбору средств. Еще мы сделали несколько небольших улучшений. И теперь наш контракт выглядит почти как настоящий!

Ему не хватает только одной вещи — бонусов для тех инвесторов кто вкладывается пораньше. Поэтому в следующем уроке мы продолжим изучать как написать смарт-контракт ICO на эфире и займемся бонусами!

Продолжение читать тут.

Войдите или Зарегистрируйтесь чтобы комментировать.