Привет, незнакомец!

Похоже, вы здесь новенький. Чтобы принять участие, нажмите одну из кнопок ниже!

Смарт-контракт на Solidity: Часть 10 — ICO, исходники на Etherscan, типы эмиссии

отредактировано November 2017 Раздел: Смарт Контракты

Серия уроков были взяты с сайте inaword.ru

В предыдущей статье мы научились добавлять бонусы и закончили писать контракты для проведения ICO. В этой статье мы коснемся некоторых тонкостей реализации и работы со смарт-контрактами ICO. А именно:
1. Узнаем как добавить исходники на etherscan
2. Познакомимся с типами эмиссий токенов и BurnableToken
3. Познакомимся с архитектурой со множеством этапов распродаж

Как добавить исходники на Etherscan

Если посмотрите на чужие контракты в etherscan, то можете заметить что у многих присутствует исходный код и вкладка «Read Smart Contract». На этой вкладке удобно представлен интерфейс.

Если же вы посмотрите на свой только что залитый контракт то увидите только две вкладки.

При этом на вкладке «Contract code» ничего кроме байткода не будет. Давайте научимся делать интерфейс для нашего контракта в etherscan.

  1. Откройте etherscan и найдите по адресу свой контракт
  2. Нажмите на вкладку «Contract code»
  3. В поле «Contract Name» укажите имя вашего контракта. В поле Compiler версию, которой компилировали контракт во время заливки в блокчейн (именно версию компилятора а не ту версию которая у вас в верху контракта «pragma solidity 0.4….». ). А в после Optimization выберите с оптимизацией компилировали или нет. Если не помните, то по-умолчанию оптимизация выключена в Parity и remix. В Mist оптимизация включена. Версия компилятора в remix обычно самая последняя как и в parity (на момент написания статьи). Mist на момент написания статьи поддерживал не самую последнюю версию 0.4.13.
  4. В поле «Enter the Solidity Contract Code» вставьте весь код смарт-контракта со всеми зависимостями. И нажмите на кнопку низу «Verify And Publish».
  5. Если версии компилятора и оптимизация указаны верно, то получите сообщение об успешно выполнении. В котором нажмите на ссылку рядом с зеленой надписью. Если получите сообщение об ошибке, то скорее всего не верно указан компилятор.

Теперь на вкладке «Contract code» отображается код нашего контракта и заодно ABI интерфейс.

А на вкладке «Read Smart Contract» отображается интерфейс на чтение смарт-контракта.

В данном случае я залил контракт нашего токена. Однако, как вы видите, токен отображается как обычный смарт-контракт. Для того чтобы отобразить наш контракт именно как токен ERC20 нужно в URL в браузере поменять «address» на «token«. В моем случае был URL:

https://ropsten.etherscan.io/address/0x275f215a3bfc4699e7278f4e521c0ed43d6011aa#readContract

После замены получаем:

https://ropsten.etherscan.io/token/0x275f215a3bfc4699e7278f4e521c0ed43d6011aa#readContract

В вашем случае слово ropsten в URL может отсутствовать. Ropsten — это просто тестовая сеть, но об этом позже. После замены мы увидим что etherscan отобразит наш контракт как токен ERC20.

Теперь появилась вкладка «Token holders». На ней будут отображаться адреса владельцев наших токенов и процент владения от общей суммы токенов. И появилась «Token transaction». На которой будут отображаться все события Transfer.

Типы эмисси токенов и BurnableToken

В наших предыдущих контрактах эмиссия токенов осуществлялась в момент, когда инвестор вкладывал деньги. Однако, есть и другой тип эмиссии. Когда все токены выпускаются ограниченным количеством при создании контракта. А в последствие перемещаются на счет инвестора тогда, когда происходит оплата.

Жизненный цикл контракта такого токена:

  1. Во время создания контракта: на адрес владельца контракта записываются все токены.
  2. Распродажа токенов: с адреса владельца контракта списывается токены и записываются на адрес инвесторов. При каждой покупке возникает событие Transfer.
  3. Распределение токенов основателям и на баунти: Ну тут все понятно.
  4. Сжигание нераспроданных токенов: токены, которые не были распроданы подлежат уничтожению или «сжиганию». При сжигании токенов генерируется событие Burn.

Зачем сжигать токены? Дело в том что за оставшиеся токены никто не заплатил. Есть купленные инвесторами токены, есть процент токенов на баунти, есть процент основателям. И есть токены которые никто не купил. Если мы их оставляем на балансе владельца контракта, то фактически оставляем возможность выпуска этих токенов на биржу. Тем самым мы размываем цену. А это не очень приятно для инвестора. Очень важно указывать в WhitePaper тот факт что вы обязуетесь нераспроданные токены сжечь! А также укажите когда именно вы это сделаете! К примеру, в чате проекта Polybius пользователи часто интересовались моментом сжигания нераспроданных токенов.

Что нужно чтобы сделать токены с ограниченной начальной эмиссией? Для этого достаточно сделать две вещи:

  1. В контракте токена инициализировать баланс владельца контракта всеми токенами и не забыть прописать соответсвующее число токенов в totoalSupply. Можно сделать так:

    contract SimpleCoinToken() is ... {
                ...
                uint256 public INITIAL_SUPPLY = 100000000 * 1 ether;
                ...
                function SimpleCointToken() {
                  totalSupply = INITIAL_SUPPLY;
                  balances[msg.sender] = INITIAL_SUPPLY;
                }
                ...
    }

Помним, что количество токенов указывается с учетом знаков после запятой. К примеру, в нашем токене 18 знаков после запятой. Поэтому мы умножаем на 1 ether (1 ether = 1000000000000000000 wei).

  1. Сделать возможность уничтожать токены. Лучше воспользоваться готовым решенем. Например от OpenZepplein. И наследоваться от BurnableToken. Наследование от MintableToken нам не нужно, поэтому его убираем. Давайте взглянем на реализацию BurnableToken.

     contract BurnableToken is StandardToken {
    
          function burn(uint _value) public {
            require(_value > 0);
            address burner = msg.sender;
            balances[burner] = balances[burner].sub(_value);
            totalSupply = totalSupply.sub(_value);
            Burn(burner, _value);
          }
    
          event Burn(address indexed burner, uint indexed value);
    
     }
    

К контракту токена добавляется функция Burn. Она и предоставляет возможность сжигать токены со своего и только своего баланса тому кто вызывает эту функцию. Если пользователь попытается сжечь токенов больше чем нужно, то библиотека безопасных математических операций, в частности функция sub, не позволит это сделать.

Фактически диаграмма наследования для токена с ограниченной эмиссией по структуре остается такой же как и раньше. Только вместо MintableToken мы наследуемся от BurnableToken.

Теперь полная реализация нашего токена выглядит так:

pragma solidity ^0.4.16;

/**
 * @title ERC20Basic
 * @dev Simpler version of ERC20 interface
 * @dev see https://github.com/ethereum/EIPs/issues/179
 */
contract ERC20Basic {
  uint256 public totalSupply;
  function balanceOf(address who) constant returns (uint256);
  function transfer(address to, uint256 value) returns (bool);
  event Transfer(address indexed from, address indexed to, uint256 value);
}

/**
 * @title ERC20 interface
 * @dev see https://github.com/ethereum/EIPs/issues/20
 */
contract ERC20 is ERC20Basic {
  function allowance(address owner, address spender) constant returns (uint256);
  function transferFrom(address from, address to, uint256 value) returns (bool);
  function approve(address spender, uint256 value) returns (bool);
  event Approval(address indexed owner, address indexed spender, uint256 value);
}

/**
 * @title SafeMath
 * @dev Math operations with safety checks that throw on error
 */
library SafeMath {

  function mul(uint256 a, uint256 b) internal constant returns (uint256) {
    uint256 c = a * b;
    assert(a == 0 || c / a == b);
    return c;
  }

  function div(uint256 a, uint256 b) internal constant returns (uint256) {
    // assert(b > 0); // Solidity automatically throws when dividing by 0
    uint256 c = a / b;
    // assert(a == b * c + a % b); // There is no case in which this doesn't hold
    return c;
  }

  function sub(uint256 a, uint256 b) internal constant returns (uint256) {
    assert(b <= a);
    return a - b;
  }

  function add(uint256 a, uint256 b) internal constant returns (uint256) {
    uint256 c = a + b;
    assert(c >= a);
    return c;
  }

}

/**
 * @title Basic token
 * @dev Basic version of StandardToken, with no allowances. 
 */
contract BasicToken is ERC20Basic {

  using SafeMath for uint256;

  mapping(address => uint256) balances;

  /**
  * @dev transfer token for a specified address
  * @param _to The address to transfer to.
  * @param _value The amount to be transferred.
  */
  function transfer(address _to, uint256 _value) returns (bool) {
    balances[msg.sender] = balances[msg.sender].sub(_value);
    balances[_to] = balances[_to].add(_value);
    Transfer(msg.sender, _to, _value);
    return true;
  }

  /**
  * @dev Gets the balance of the specified address.
  * @param _owner The address to query the the balance of. 
  * @return An uint256 representing the amount owned by the passed address.
  */
  function balanceOf(address _owner) constant returns (uint256 balance) {
    return balances[_owner];
  }

}

/**
 * @title Standard ERC20 token
 *
 * @dev Implementation of the basic standard token.
 * @dev https://github.com/ethereum/EIPs/issues/20
 * @dev Based on code by FirstBlood: https://github.com/Firstbloodio/token/blob/master/smart_contract/FirstBloodToken.sol
 */
contract StandardToken is ERC20, BasicToken {

  mapping (address => mapping (address => uint256)) allowed;

  /**
   * @dev Transfer tokens from one address to another
   * @param _from address The address which you want to send tokens from
   * @param _to address The address which you want to transfer to
   * @param _value uint256 the amout of tokens to be transfered
   */
  function transferFrom(address _from, address _to, uint256 _value) returns (bool) {
    var _allowance = allowed[_from][msg.sender];

    // Check is not needed because sub(_allowance, _value) will already throw if this condition is not met
    // require (_value <= _allowance);

    balances[_to] = balances[_to].add(_value);
    balances[_from] = balances[_from].sub(_value);
    allowed[_from][msg.sender] = _allowance.sub(_value);
    Transfer(_from, _to, _value);
    return true;
  }

  /**
   * @dev Aprove the passed address to spend the specified amount of tokens on behalf of msg.sender.
   * @param _spender The address which will spend the funds.
   * @param _value The amount of tokens to be spent.
   */
  function approve(address _spender, uint256 _value) returns (bool) {

    // To change the approve amount you first have to reduce the addresses`
    //  allowance to zero by calling `approve(_spender, 0)` if it is not
    //  already 0 to mitigate the race condition described here:
    //  https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
    require((_value == 0) || (allowed[msg.sender][_spender] == 0));

    allowed[msg.sender][_spender] = _value;
    Approval(msg.sender, _spender, _value);
    return true;
  }

  /**
   * @dev Function to check the amount of tokens that an owner allowed to a spender.
   * @param _owner address The address which owns the funds.
   * @param _spender address The address which will spend the funds.
   * @return A uint256 specifing the amount of tokens still available for the spender.
   */
  function allowance(address _owner, address _spender) constant returns (uint256 remaining) {
    return allowed[_owner][_spender];
  }

}

/**
 * @title Ownable
 * @dev The Ownable contract has an owner address, and provides basic authorization control
 * functions, this simplifies the implementation of "user permissions".
 */
contract Ownable {

  address public owner;

  /**
   * @dev The Ownable constructor sets the original `owner` of the contract to the sender
   * account.
   */
  function Ownable() {
    owner = msg.sender;
  }

  /**
   * @dev Throws if called by any account other than the owner.
   */
  modifier onlyOwner() {
    require(msg.sender == owner);
    _;
  }

  /**
   * @dev Allows the current owner to transfer control of the contract to a newOwner.
   * @param newOwner The address to transfer ownership to.
   */
  function transferOwnership(address newOwner) onlyOwner {
    require(newOwner != address(0));      
    owner = newOwner;
  }

}

/**
 * @title Burnable Token
 * @dev Token that can be irreversibly burned (destroyed).
 */
contract BurnableToken is StandardToken {

  /**
   * @dev Burns a specific amount of tokens.
   * @param _value The amount of token to be burned.
   */
  function burn(uint _value) public {
    require(_value > 0);
    address burner = msg.sender;
    balances[burner] = balances[burner].sub(_value);
    totalSupply = totalSupply.sub(_value);
    Burn(burner, _value);
  }

  event Burn(address indexed burner, uint indexed value);

}

contract SimpleCoinToken is BurnableToken {

  string public constant name = "Simple Coin Token";

  string public constant symbol = "SCT";

  uint32 public constant decimals = 18;

  uint256 public INITIAL_SUPPLY = 100000000 * 1 ether;

  function SimpleCoinToken() {
    totalSupply = INITIAL_SUPPLY;
    balances[msg.sender] = INITIAL_SUPPLY;
  }

}

А теперь исправим наш контракт Crowdsale. Раньше, когда инвестор покупал токены мы вызывали mint у контракта токена. Теперь нам достаточно вызвать transfer и переместить токены со счета владельца контракта токена на счет инвестора. Для этого в функции createTokens достаточно заменить последнюю строчку

token.mint(msg.sender, tokensWithBonus);
на
token.transfer(msg.sender, tokensWithBonus);

Функцию finishMinting так просто исправить не получится. Раньше она выполняла две задачи:
1. Cчитала процент токенов для основателей и баунти по окончанию распродажи. Причем процент считался от totoalSupply. Раньше totalSupply — количество выпущенных токенов соответствовало количеству купленных. Теперь это не так. А считать нам нужно процент именно от купленных, иначе получится размывание цены токена.
2. Запрещала всякую эмиссию после окончания распродажи
token.finishMinting();

Чтобы процент токенов основателям считался корректно — мы будем считать его непосредственно при покупке токенов инвесторами и тут же перечислять на счет основателей. Для этого в конец createTokens добавим две строчки.

uint restrictedTokens = tokens.mul(restrictedPercent).div(100 - restrictedPercent);
token.transfer(restricted, restrictedTokens);

Поскольку токены у нас выпускаются единожды и больше возможности выпуска нет, то запрещать эмиссию нет смысла в конце распродажи. Поэтому функцию finishMinting теперь можно просто убрать.

Также из контракта распродажи можно смело убрать ограничение isUnderHardcap. Как только все токены закончатся, функция покупки перестанет работать и все. Давайте теперь посмотри как выглядит весь код нашего ICO.

pragma solidity ^0.4.16;

/**
 * @title ERC20Basic
 * @dev Simpler version of ERC20 interface
 * @dev see https://github.com/ethereum/EIPs/issues/179
 */
contract ERC20Basic {
  uint256 public totalSupply;
  function balanceOf(address who) constant returns (uint256);
  function transfer(address to, uint256 value) returns (bool);
  event Transfer(address indexed from, address indexed to, uint256 value);
}

/**
 * @title ERC20 interface
 * @dev see https://github.com/ethereum/EIPs/issues/20
 */
contract ERC20 is ERC20Basic {
  function allowance(address owner, address spender) constant returns (uint256);
  function transferFrom(address from, address to, uint256 value) returns (bool);
  function approve(address spender, uint256 value) returns (bool);
  event Approval(address indexed owner, address indexed spender, uint256 value);
}

/**
 * @title SafeMath
 * @dev Math operations with safety checks that throw on error
 */
library SafeMath {

  function mul(uint256 a, uint256 b) internal constant returns (uint256) {
    uint256 c = a * b;
    assert(a == 0 || c / a == b);
    return c;
  }

  function div(uint256 a, uint256 b) internal constant returns (uint256) {
    // assert(b > 0); // Solidity automatically throws when dividing by 0
    uint256 c = a / b;
    // assert(a == b * c + a % b); // There is no case in which this doesn't hold
    return c;
  }

  function sub(uint256 a, uint256 b) internal constant returns (uint256) {
    assert(b <= a);
    return a - b;
  }

  function add(uint256 a, uint256 b) internal constant returns (uint256) {
    uint256 c = a + b;
    assert(c >= a);
    return c;
  }

}

/**
 * @title Basic token
 * @dev Basic version of StandardToken, with no allowances. 
 */
contract BasicToken is ERC20Basic {

  using SafeMath for uint256;

  mapping(address => uint256) balances;

  /**
  * @dev transfer token for a specified address
  * @param _to The address to transfer to.
  * @param _value The amount to be transferred.
  */
  function transfer(address _to, uint256 _value) returns (bool) {
    balances[msg.sender] = balances[msg.sender].sub(_value);
    balances[_to] = balances[_to].add(_value);
    Transfer(msg.sender, _to, _value);
    return true;
  }

  /**
  * @dev Gets the balance of the specified address.
  * @param _owner The address to query the the balance of. 
  * @return An uint256 representing the amount owned by the passed address.
  */
  function balanceOf(address _owner) constant returns (uint256 balance) {
    return balances[_owner];
  }

}

/**
 * @title Standard ERC20 token
 *
 * @dev Implementation of the basic standard token.
 * @dev https://github.com/ethereum/EIPs/issues/20
 * @dev Based on code by FirstBlood: https://github.com/Firstbloodio/token/blob/master/smart_contract/FirstBloodToken.sol
 */
contract StandardToken is ERC20, BasicToken {

  mapping (address => mapping (address => uint256)) allowed;

  /**
   * @dev Transfer tokens from one address to another
   * @param _from address The address which you want to send tokens from
   * @param _to address The address which you want to transfer to
   * @param _value uint256 the amout of tokens to be transfered
   */
  function transferFrom(address _from, address _to, uint256 _value) returns (bool) {
    var _allowance = allowed[_from][msg.sender];

    // Check is not needed because sub(_allowance, _value) will already throw if this condition is not met
    // require (_value <= _allowance);

    balances[_to] = balances[_to].add(_value);
    balances[_from] = balances[_from].sub(_value);
    allowed[_from][msg.sender] = _allowance.sub(_value);
    Transfer(_from, _to, _value);
    return true;
  }

  /**
   * @dev Aprove the passed address to spend the specified amount of tokens on behalf of msg.sender.
   * @param _spender The address which will spend the funds.
   * @param _value The amount of tokens to be spent.
   */
  function approve(address _spender, uint256 _value) returns (bool) {

    // To change the approve amount you first have to reduce the addresses`
    //  allowance to zero by calling `approve(_spender, 0)` if it is not
    //  already 0 to mitigate the race condition described here:
    //  https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
    require((_value == 0) || (allowed[msg.sender][_spender] == 0));

    allowed[msg.sender][_spender] = _value;
    Approval(msg.sender, _spender, _value);
    return true;
  }

  /**
   * @dev Function to check the amount of tokens that an owner allowed to a spender.
   * @param _owner address The address which owns the funds.
   * @param _spender address The address which will spend the funds.
   * @return A uint256 specifing the amount of tokens still available for the spender.
   */
  function allowance(address _owner, address _spender) constant returns (uint256 remaining) {
    return allowed[_owner][_spender];
  }

}

/**
 * @title Ownable
 * @dev The Ownable contract has an owner address, and provides basic authorization control
 * functions, this simplifies the implementation of "user permissions".
 */
contract Ownable {

  address public owner;

  /**
   * @dev The Ownable constructor sets the original `owner` of the contract to the sender
   * account.
   */
  function Ownable() {
    owner = msg.sender;
  }

  /**
   * @dev Throws if called by any account other than the owner.
   */
  modifier onlyOwner() {
    require(msg.sender == owner);
    _;
  }

  /**
   * @dev Allows the current owner to transfer control of the contract to a newOwner.
   * @param newOwner The address to transfer ownership to.
   */
  function transferOwnership(address newOwner) onlyOwner {
    require(newOwner != address(0));      
    owner = newOwner;
  }

}

/**
 * @title Burnable Token
 * @dev Token that can be irreversibly burned (destroyed).
 */
contract BurnableToken is StandardToken {

  /**
   * @dev Burns a specific amount of tokens.
   * @param _value The amount of token to be burned.
   */
  function burn(uint _value) public {
    require(_value > 0);
    address burner = msg.sender;
    balances[burner] = balances[burner].sub(_value);
    totalSupply = totalSupply.sub(_value);
    Burn(burner, _value);
  }

  event Burn(address indexed burner, uint indexed value);

}

contract SimpleCoinToken is BurnableToken {

  string public constant name = "Simple Coin Token";

  string public constant symbol = "SCT";

  uint32 public constant decimals = 18;

  uint256 public INITIAL_SUPPLY = 100000000 * 1 ether;

  function SimpleCoinToken() {
    totalSupply = INITIAL_SUPPLY;
    balances[msg.sender] = INITIAL_SUPPLY;
  }

}

contract Crowdsale is Ownable {

  using SafeMath for uint;

  address multisig;

  uint restrictedPercent;

  address restricted;

  SimpleCoinToken public token = new SimpleCoinToken();

  uint start;

  uint period;

  uint rate;

  function Crowdsale() {
    multisig = 0xEA15Adb66DC92a4BbCcC8Bf32fd25E2e86a2A770;
    restricted = 0xb3eD172CC64839FB0C0Aa06aa129f402e994e7De;
    restrictedPercent = 40;
    rate = 100000000000000000000;
    start = 1500379200;
    period = 28;
  }

  modifier saleIsOn() {
    require(now > start && now < start + period * 1 days);
    _;
  }

  function createTokens() saleIsOn payable {
    multisig.transfer(msg.value);
    uint tokens = rate.mul(msg.value).div(1 ether);
    uint bonusTokens = 0;
    if(now < start + (period * 1 days).div(4)) {
      bonusTokens = tokens.div(4);
    } else if(now >= start + (period * 1 days).div(4) && now < start + (period * 1 days).div(4).mul(2)) {
      bonusTokens = tokens.div(10);
    } else if(now >= start + (period * 1 days).div(4).mul(2) && now < start + (period * 1 days).div(4).mul(3)) {
      bonusTokens = tokens.div(20);
    }
    uint tokensWithBonus = tokens.add(bonusTokens);
    token.transfer(msg.sender, tokensWithBonus);
    uint restrictedTokens = tokens.mul(restrictedPercent).div(100 - restrictedPercent);
    token.transfer(restricted, restrictedTokens);
  }

  function() external payable {
    createTokens();
  }

}

При тестировании контракта не забывайте менять дату начала распродажи.

Между токенами с эмиссией во время распродажи и с ограниченной эмиссией вначале есть тонкое различие для отображения в etherscan.

Дело в том что etherscan вычисляет владельцев токенов и их доли только на основе события Transfer. В контракте токена с изначальной эмиссией все токены уже выпущены. Когда инвестор делает покупку токены просто перечисляются на счет инвестора с помощью функции transfer. A transfer генерирует событие Transfer. Поэтому доля инвестора вычисляется сразу корректно относительно суммы всех выпущенных токенов. Однако событие уничтожения токенов Burn не воспринимается etherscan. Поэтому доли останются рассчитаными относительно изначального числа токенов.

В том случае когда эмиссия происходит во время покупки, возникает событие Mint а не Transfer. Поэтому etherscan не сможет вычислять и отображать доли держателей токенов корректно. Такое будет до тех пор пока все держатели не выполнят хотя бы одно перемещение токенов.

Однако, в токене с эмиссией во время распродажи проблему можно решить. Нужно не сразу выпускать токены на счет инвестора. Нужно сначала делать эмиссию на счет владельца контракта . И только после этого перемещать токены со счета владельца контракта на счет инвестора (попробуйте это сделать самостоятельно). В таком случае все доли будут отображаться в etherscan корректно. В случае же с токеном с изначальной эмиссией решения этой проблемы нет.

Часто встречаются ICO в которых указывается изначально выпущенное количество токенов с аргументом: «инвесторы хотят знать сколько токенов выпущено всего«. На самом деле, если нераспроданные токены будут сжигаться (а сжигаться они должны если вы не обманываете инвесторов), то конечное число токенов никому не известно. Поэтому я всегда рекомендую выбирать реализацию с выпуском токенов во время распродажи. Но выбор конечно же за вами вам.

Архитектура со множеством этапов раcпродаж

Кроме основной распродажи может быть предварительный этап продажи токенов. Так называемый pre sale. Если этапов распродажи токенов может быть много, то создают один контракт токена. А на каждую распродажу свой делают отдельный контракт. При этом контракт токена имеет поле saleAgent. В этом поле хранится адрес того контракта распродажи, который в данный момент имеет право эмитировать или продавать токены. Устанавливать это поле имеет право только владелец контракта токена. А эмитировать токены имеет право только тот контракт, который указан в saleAgent.

Продолжение читать тут.

Войдите или Зарегистрируйтесь чтобы комментировать.