Привет, незнакомец!

Похоже, вы здесь новенький. Чтобы принять участие, нажмите одну из кнопок ниже!

Смарт-контракт на Solidity: Часть 11 — ICO, refund — возврат средств по softcap

отредактировано November 2017 Раздел: Смарт Контракты

Серия уроков были взяты с сайте inaword.ru

В предыдущей статье мы познакомились с видами эмиссий и научились верифицировать контракт в etherscan. Теперь наша задача создать механизм возврата средств, тем самым повысив доверие инвесторов.

В некоторых ICO для реализации проекта необходима какая-то минимальная сумма. Так называемый softcap. Если основатели ее не собирают, то проект выполнить невозможно.

Зачем нужен механизм возврата средств по softcap?

  1. Если во время ICO softcap не был достигнут, то получается что и деньги у вас и проект не будет выполнен. В этом случае, если вы не вернете средства, то инвесторы могут посчитать вас обманщиком.
  2. Наличие возврата денег повышает доверие инвесторов.

Когда возврат по softcap не нужен?
1. Если ваш проект не имеет минимальной суммы для реализации. Например, если у вас проект по инвестициям в валюты, то тут минимальная сумма не нужна. В любом случае можно инвестировать любую сумму.
2. Когда вы четко прописываете в WhitePaper, что при недостижении softcap инвестиции не возвращаются (это может быть оправдано как покрытие расходов на запуск ICO).
3. Если вы достаточно уверены в том, что соберете softcap. Такая уверенность может основываться на результатах сбора во время presale например.

Как сделать механизм возврата средств?
Возврат средств может быть реализован как на пресейле так и на ICO. Работает он достаточно просто. Во время ICO средства инвесторов перечисляются не специальный счет-контракт. С этого счета основатели не могут вывести деньги до окончания ICO. По окончанию можно проверить — достигнут ли softcap. Если не достигнут, то средства остаются на специальном счете и инвесторы могут вернуть себе средства путем вызова специальной функции возврата. Обычно ее называют refund. Если же softcap был достигнут, то средства со спец-счета переводятся на счет основателей.

Давайте приступим к нашей реализации. За основу мы возьмем код 9-го урока.

Для простоты средства инвесторов у нас будут собираются на счету контракта распродажи.

Нижняя граница сборов softcap у нас будет хранится в переменной sotfcap.

uint softcap;

Если softcap не достигнут и ICO закончено, то пользователи смогут вывести средства с помощью функции refund.

function refund() {
  require(this.balance < softcap && now > start + period * 1 days);
  ...
}

Вначале идет проверка, что баланс контракта больше softcap и что ICO уже закончилось. Но как же нам возвращать средства инвесторов, если мы не знаем сколько каждый инвестировал?

Для этого во время инвестирования мы будем сохранять адрес инвестора и сколько он инвестировал в мэпе:
mapping(address => uint) public balances;

Поправим функцию продажи токена, чтобы она сохраняла сумму инвестора. Добавим строчку в конец. И уберем перечисление средств на multisig. Теперь средства остаются на контракте распродажи.

function createTokens() isUnderHardCap saleIsOn payable {
  ...
  balances[msg.sender] = balances[msg.sender].add(msg.value);
}

Теперь мы наконец можем дописать нашу функцию возврата средств.

function refund() {
  require(this.balance < softcap && now > start + period * 1 days);
  uint value = balances[msg.sender];
  balances[msg.sender] = 0;
  msg.sender.transfer(value);
}

В конце ICO при вызове finishMinting мы будем определять достигнут ли softcap. И если достигнут то будем переводить все средства с аккаунта контракта на кошелек основателей. Также все остальные действия из этой функции будут выполняться только в случае достижения softcap. Иначе они не имеют смысла.

function finishMinting() public onlyOwner {
      if(this.balance > softcap) {
        multisig.transfer(this.balance);
        uint issuedTokenSupply = token.totalSupply();
    uint restrictedTokens = issuedTokenSupply.mul(restrictedPercent).div(100 - restrictedPercent);
        token.mint(restricted, restrictedTokens);
        token.finishMinting();
      }
}

На этом наши доработки закончились, вот весь код.

pragma solidity ^0.4.15;

/**
 * @title ERC20Basic
 * @dev Simpler version of ERC20 interface
 * @dev see https://github.com/ethereum/EIPs/issues/179
 */
contract ERC20Basic {
  uint256 public totalSupply;
  function balanceOf(address who) constant returns (uint256);
  function transfer(address to, uint256 value) returns (bool);
  event Transfer(address indexed from, address indexed to, uint256 value);
}

/**
 * @title ERC20 interface
 * @dev see https://github.com/ethereum/EIPs/issues/20
 */
contract ERC20 is ERC20Basic {
  function allowance(address owner, address spender) constant returns (uint256);
  function transferFrom(address from, address to, uint256 value) returns (bool);
  function approve(address spender, uint256 value) returns (bool);
  event Approval(address indexed owner, address indexed spender, uint256 value);
}

/**
 * @title SafeMath
 * @dev Math operations with safety checks that throw on error
 */
library SafeMath {

  function mul(uint256 a, uint256 b) internal constant returns (uint256) {
    uint256 c = a * b;
    assert(a == 0 || c / a == b);
    return c;
  }

  function div(uint256 a, uint256 b) internal constant returns (uint256) {
    // assert(b > 0); // Solidity automatically throws when dividing by 0
    uint256 c = a / b;
    // assert(a == b * c + a % b); // There is no case in which this doesn't hold
    return c;
  }

  function sub(uint256 a, uint256 b) internal constant returns (uint256) {
    assert(b <= a);
    return a - b;
  }

  function add(uint256 a, uint256 b) internal constant returns (uint256) {
    uint256 c = a + b;
    assert(c >= a);
    return c;
  }

}

/**
 * @title Basic token
 * @dev Basic version of StandardToken, with no allowances. 
 */
contract BasicToken is ERC20Basic {

  using SafeMath for uint256;

  mapping(address => uint256) balances;

  /**
  * @dev transfer token for a specified address
  * @param _to The address to transfer to.
  * @param _value The amount to be transferred.
  */
  function transfer(address _to, uint256 _value) returns (bool) {
    balances[msg.sender] = balances[msg.sender].sub(_value);
    balances[_to] = balances[_to].add(_value);
    Transfer(msg.sender, _to, _value);
    return true;
  }

  /**
  * @dev Gets the balance of the specified address.
  * @param _owner The address to query the the balance of. 
  * @return An uint256 representing the amount owned by the passed address.
  */
  function balanceOf(address _owner) constant returns (uint256 balance) {
    return balances[_owner];
  }

}

/**
 * @title Standard ERC20 token
 *
 * @dev Implementation of the basic standard token.
 * @dev https://github.com/ethereum/EIPs/issues/20
 * @dev Based on code by FirstBlood: https://github.com/Firstbloodio/token/blob/master/smart_contract/FirstBloodToken.sol
 */
contract StandardToken is ERC20, BasicToken {

  mapping (address => mapping (address => uint256)) allowed;

  /**
   * @dev Transfer tokens from one address to another
   * @param _from address The address which you want to send tokens from
   * @param _to address The address which you want to transfer to
   * @param _value uint256 the amout of tokens to be transfered
   */
  function transferFrom(address _from, address _to, uint256 _value) returns (bool) {
    var _allowance = allowed[_from][msg.sender];

    // Check is not needed because sub(_allowance, _value) will already throw if this condition is not met
    // require (_value <= _allowance);

    balances[_to] = balances[_to].add(_value);
    balances[_from] = balances[_from].sub(_value);
    allowed[_from][msg.sender] = _allowance.sub(_value);
    Transfer(_from, _to, _value);
    return true;
  }

  /**
   * @dev Aprove the passed address to spend the specified amount of tokens on behalf of msg.sender.
   * @param _spender The address which will spend the funds.
   * @param _value The amount of tokens to be spent.
   */
  function approve(address _spender, uint256 _value) returns (bool) {

    // To change the approve amount you first have to reduce the addresses`
    //  allowance to zero by calling `approve(_spender, 0)` if it is not
    //  already 0 to mitigate the race condition described here:
    //  https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
    require((_value == 0) || (allowed[msg.sender][_spender] == 0));

    allowed[msg.sender][_spender] = _value;
    Approval(msg.sender, _spender, _value);
    return true;
  }

  /**
   * @dev Function to check the amount of tokens that an owner allowed to a spender.
   * @param _owner address The address which owns the funds.
   * @param _spender address The address which will spend the funds.
   * @return A uint256 specifing the amount of tokens still available for the spender.
   */
  function allowance(address _owner, address _spender) constant returns (uint256 remaining) {
    return allowed[_owner][_spender];
  }

}

/**
 * @title Ownable
 * @dev The Ownable contract has an owner address, and provides basic authorization control
 * functions, this simplifies the implementation of "user permissions".
 */
contract Ownable {

  address public owner;

  /**
   * @dev The Ownable constructor sets the original `owner` of the contract to the sender
   * account.
   */
  function Ownable() {
    owner = msg.sender;
  }

  /**
   * @dev Throws if called by any account other than the owner.
   */
  modifier onlyOwner() {
    require(msg.sender == owner);
    _;
  }

  /**
   * @dev Allows the current owner to transfer control of the contract to a newOwner.
   * @param newOwner The address to transfer ownership to.
   */
  function transferOwnership(address newOwner) onlyOwner {
    require(newOwner != address(0));      
    owner = newOwner;
  }

}

/**
 * @title Mintable token
 * @dev Simple ERC20 Token example, with mintable token creation
 * @dev Issue: * https://github.com/OpenZeppelin/zeppelin-solidity/issues/120
 * Based on code by TokenMarketNet: https://github.com/TokenMarketNet/ico/blob/master/contracts/MintableToken.sol
 */

contract MintableToken is StandardToken, Ownable {

  event Mint(address indexed to, uint256 amount);

  event MintFinished();

  bool public mintingFinished = false;

  modifier canMint() {
    require(!mintingFinished);
    _;
  }

  /**
   * @dev Function to mint tokens
   * @param _to The address that will recieve the minted tokens.
   * @param _amount The amount of tokens to mint.
   * @return A boolean that indicates if the operation was successful.
   */
  function mint(address _to, uint256 _amount) onlyOwner canMint returns (bool) {
    totalSupply = totalSupply.add(_amount);
    balances[_to] = balances[_to].add(_amount);
    Mint(_to, _amount);
    return true;
  }

  /**
   * @dev Function to stop minting new tokens.
   * @return True if the operation was successful.
   */
  function finishMinting() onlyOwner returns (bool) {
    mintingFinished = true;
    MintFinished();
    return true;
  }

}

contract SimpleTokenCoin is MintableToken {

    string public constant name = "Simple Coint Token";

    string public constant symbol = "SCT";

    uint32 public constant decimals = 18;

}


contract Crowdsale is Ownable {

    using SafeMath for uint;

    address public multisig;

    uint public restrictedPercent;

    address public restricted;

    SimpleTokenCoin public token = new SimpleTokenCoin();

    uint public start;

    uint public period;

    uint public hardcap;

    uint public rate;

    uint public softcap;

    mapping(address => uint) public balances;

    function Crowdsale() {
      multisig = 0xEA15Adb66DC92a4BbCcC8Bf32fd25E2e86a2A770;
      restricted = 0xb3eD172CC64839FB0C0Aa06aa129f402e994e7De;
      restrictedPercent = 40;
      rate = 100000000000000000000;
      start = 1500379200;
      period = 28;
      hardcap = 10000000000000000000000;
      softcap = 1000000000000000000000;
    }

    modifier saleIsOn() {
      require(now > start && now < start + period * 1 days);
      _;
    }

    modifier isUnderHardCap() {
      require(multisig.balance <= hardcap);
      _;
    }

    function refund() {
      require(this.balance < softcap && now > start + period * 1 days);
      uint value = balances[msg.sender]; 
      balances[msg.sender] = 0; 
      msg.sender.transfer(value); 
    }

    function finishMinting() public onlyOwner {
      if(this.balance > softcap) {
        multisig.transfer(this.balance);
        uint issuedTokenSupply = token.totalSupply();
        uint restrictedTokens = issuedTokenSupply.mul(restrictedPercent).div(100 - restrictedPercent);
        token.mint(restricted, restrictedTokens);
        token.finishMinting();
      }
    }

   function createTokens() isUnderHardCap saleIsOn payable {
      uint tokens = rate.mul(msg.value).div(1 ether);
      uint bonusTokens = 0;
      if(now < start + (period * 1 days).div(4)) {
        bonusTokens = tokens.div(4);
      } else if(now >= start + (period * 1 days).div(4) && now < start + (period * 1 days).div(4).mul(2)) {
        bonusTokens = tokens.div(10);
      } else if(now >= start + (period * 1 days).div(4).mul(2) && now < start + (period * 1 days).div(4).mul(3)) {
        bonusTokens = tokens.div(20);
      }
      tokens += bonusTokens;
      token.mint(msg.sender, tokens);
      balances[msg.sender] = balances[msg.sender].add(msg.value);
    }

    function() external payable {
      createTokens();
    }

}

Теперь наши инвесторы могут быть уверены, что смогут забрать средства, если проект не вложений будет недостаточно для реализации проекта.

Вы можете спросить — почему нельзя автоматически вернуть средства? Почему именно сам инвестор должен вызвать refund, чтобы вернуть? Дело в том что на каждую инструкцию тратится газ. Представьте что у нас несколько тысяч инвесторов. В этом случае расходы на рассылку резко возрастут. Именно поэтому мы не делаем автоматическое возвращение средств в finishMinting.

Как уже знаете всегда лучше использовать готовое решение. Refund — это хорошо известный механизм и он имеет свою реализацию в OpenZepplein. Она гораздо сложнее чем та что описана в этой статье, но принцип тот-же. Эта реализация состоит из двух контрактов.

  1. RefundableCrowdsale — контракт для проведения ICO с возможностью возврата средств.
  2. RefunValut — специальный контракт-счет для хранения средств до окончания ICO.

Разбор шаблона OpenZepplin оставим для самостоятельной подготовки.

Продолжение читать тут.

Войдите или Зарегистрируйтесь чтобы комментировать.