Привет, незнакомец!

Похоже, вы здесь новенький. Чтобы принять участие, нажмите одну из кнопок ниже!

Смарт-контракт на Solidity: Частина 8 — ICO рефакторинг, виділення токенів для баунті та команди

отредактировано December 2017 Раздел: Смарт Контракты

Серія уроків була взята з сайту inaword.ru

Минулого уроку ми написали наш перший ІСО смарт-контракт! На цьому уроці ми продовжимо вивчати як написати смарт-контракт ІСО на ефірі. А також, додамо деякі удосконалення:
1. Встановимо межу збору коштів – hardcap. Тобто, якщо зібрана необхідна сума, то продаж токенів зупиняється. Звичайно, збір коштів можна продовжити і далі, але (!) зазвичай цілі на які збираються кошти прописуються у White Paper (інформація про проект для інвесторів). І для кожної цілі вказується сума, щоб інвестор розумів, на що будуть витрачені його кошти. Якщо немає межі на збір коштів то це може здатись підозрілим.
2. Після закінчення ІСО випустимо частину токенів для власних потреб. У White Paper, як правило, прописується частка токенів, що лишається у засновників. Частина з них може лишитись для власних потреб засновників, інша ж частина піти на оплату баунті-компаній (піар-компанії в соціальних мережах, ЗМІ, блогах, форумах).
Отже, почнемо.

По-перше, винесемо код перевірки дат ІСО в модифікатор (код контракту ІСО можна подивитись в кінці попереднього уроку). Раніше перевірка виглядала так:

require(now > start && now < start + period*24*60*60);

А тепер буде як модифікатор:

modifier saleIsOn() {
        require(now > start && now < start + period * 1 days);
        _;
}

Тут уважний читач помітить, що замість множення «246060» ми використали «1 days». В solidity є вбудовані одиниці виміру (посилання на офиційну документацію). Ось вони:

  1. 1 == 1 seconds
  2. 1 minutes == 60 seconds
  3. 1 hours == 60 minutes
  4. 1 days == 24 hours
  5. 1 weeks == 7 days
  6. 1 years == 365 days

Відповідно, при їх використанні відбувається перерахунок в секунди. Тут є один нюанс. Якщо ви використовуєте число з одиницею виміру, наприклад, так:

uint time = 2 days;

то все буде працювати нормально. Якщо ж ви захочете помножити змінну і запишете так:

uint time = period * days;

То компілятор почне сваритися, і тому необхідно використовувати так:

uint time = period * 1 days;

В контракті ІСО зазвичай отриманий ефір не відправляють на адресу власника контракту, а відправляють його на окрему адресу. Це робиться тому, що за окремою адресою може бути як звичайний акаунт, так і контракт ескроу (спеціальний рахунок, керований довіреними особами в цілях підвищення довіри інвесторів – про це поговоримо в наступних уроках). В даному випадку ми будемо задавати адресу простого акаунту в конструкторі. Називатись він буде multisig.

address multisig;

Тепер додамо обмеження на суму, яку нам необхідно зібрати. Якщо всі кошти вже зібрані, то спроба користувача купити токен буде відхилятись. Для початку додамо змінну hardcap, яка буде зберігати значення необхідної суми.

uint hardcap;

Поки що задавати значення не будемо.

Все це ми зробимо в кінці, в конструкторі контракту ІСО.
Тепер напишемо модифікатор, який буде перевіряти умову по hardcap. Ми маємо верхню межу hardcap і адресу, на яку будуть відправлятися кошти, а баланс акаунту зберігається в полі balance. Запишемо наш модифікатор:

modifier isUnderHardCap() {
        require(multisig.balance <= hardcap);
        _;
}

Ще трохи рефакторингу. Винесемо код з fallback (нагадую, це функція, що викликається у контракту, коли на нього пересилають ефір) функції в окрему. Змінимо умову початку розпродажу на модифікатор и додамо модифікатор верхньої межі коштів.

    function createTokens() isUnderHardCap saleIsOn payable {
        multisig.transfer(msg.value);
        token.mint(msg.sender, msg.value);
    }

    function() external payable {
        createTokens();
    }

Для зручності додамо коефіцієнт перерахунку ефіру в наші токени. Ініціалізувати його будем також у конструкторі.

uint rate;

Тоді наша функція createTokens трохи зміниться:

function createTokens() isUnderHardCap saleIsOn payable {
        multisig.transfer(msg.value);
        uint tokens = rate.mul(msg.value).div(1 ether);
        token.mint(msg.sender, tokens);
}

Ми використовуємо операції div і mul з бібліотеки безпечних математичних операцій SafeMath (див. урок 6), тому не забуваємо її підключити.

using SafeMath for uint;

Зверніть увагу, що функція createTokens оголошена як payable, тому що ми приймаємо ефір. Помилка, коли забуваються вказати payable зустрічається дуже часто!

Тепер розберімось з випуском токенів для наших потреб. Як вже зазначалось вище, зазвичай у White Paper вказується, який процент токенів піде на розпродаж, а який лишиться для розробників та інших потреб. Наш контракт не випускає токени заздалегідь і ми не можемо знати, скільки токенів буде випущено. Тому розраховувати токени для себе ми будемо в кінці ІСО. Ми напишемо функцію finishMinting, яку самостійно будемо викликати. Вона сама розрахує і випустить токени. Для цього вкажемо рахунок – restricted. А також процент токенів, які ми хочемо отримати – restrictedPercent.

uint restrictedPercent;

address restricted;

Лишилось написати функцію для розрахунку наших токенів:

function finishMinting() public onlyOwner {
    uint issuedTokenSupply = token.totalSupply();
    uint restrictedTokens = issuedTokenSupply.mul(restrictedPercent).div(100 - restrictedPercent);
    token.mint(restricted, restrictedTokens);
        token.finishMinting();
}

У ній ми беремо у контракту токена кількість усіх випущених токенів, і розраховуємо, скільки треба довипустити restrictedTokens. Випускаємо їх на рахунок restricted. Потім викликаємо finishMinting у контракту токена – ця функція забороняє випуск нових токенів (міститься в шаблоні MintableToken, див. урок 6). Зверніть увагу, чи ви не забули використати модифікатор onlyOwner (він визначений в контракті Ownable), оскільки наша функція має викликатись лише власником контракту. В протилежному випадку завершити ІСО зможе будь-яка стороння людина.
Тепер можна подивитись як виглядає контракт після всіх змін:

contract Crowdsale is Ownable {

    using SafeMath for uint;    

    address multisig;

    uint restrictedPercent;

    address restricted;

    SimpleTokenCoin public token = new SimpleTokenCoin();

    uint start;

    uint period;

    uint hardcap;

    uint rate;

    function Crowdsale() {
    // initialize all fields
    }

    modifier saleIsOn() {
        require(now > start && now < start + period * 1 days);
        _;
    }

    modifier isUnderHardCap() {
        require(multisig.balance <= hardcap);
        _;
    }

    function finishMinting() public onlyOwner {
    uint issuedTokenSupply = token.totalSupply();
    uint restrictedTokens = issuedTokenSupply.mul(restrictedPercent).div(100 - restrictedPercent);
    token.mint(restricted, restrictedTokens);
        token.finishMinting();
    }

    function createTokens() isUnderHardCap saleIsOn payable {
        multisig.transfer(msg.value);
        uint tokens = rate.mul(msg.value).div(1 ether);
        token.mint(msg.sender, tokens);
    }

    function() external payable {
        createTokens();
    }

}

Лишилось ініціалізувати поля в конструкторі, а для цього знадобиться:

  1. Адреса, куди буде перераховуватись ефір — multisig. Нехай буде 0xEA15Adb66DC92a4BbCcC8Bf32fd25E2e86a2A770.
  2. Адреса, куди будуть перераховуватись токени для наших потреб — restricted. Нехай буде — 0xb3eD172CC64839FB0C0Aa06aa129f402e994e7De.
  3. Процент токенів на наші потреби restrictedPercent нехай буде 40%.
  4. Час початку ICO — GMT у UNIX форматі (див. урок 7) — start. Нехай буде як в 7-му уроці — 18 липня 2017 року о 15-й годині. В UNIX — 1500379200. Для тестування не забувайте змінити дату на власну!
  5. Час проведення ICO в днях — period. У нас буде 28 днів.
  6. rate у нас буде — 100000000000000000000

Після цього повний контракт з шаблонами виглядає так:

pragma solidity ^0.4.13;

/**
 * @title ERC20Basic
 * @dev Simpler version of ERC20 interface
 * @dev see https://github.com/ethereum/EIPs/issues/179
 */
contract ERC20Basic {
  uint256 public totalSupply;
  function balanceOf(address who) constant returns (uint256);
  function transfer(address to, uint256 value) returns (bool);
  event Transfer(address indexed from, address indexed to, uint256 value);
}

/**
 * @title ERC20 interface
 * @dev see https://github.com/ethereum/EIPs/issues/20
 */
contract ERC20 is ERC20Basic {
  function allowance(address owner, address spender) constant returns (uint256);
  function transferFrom(address from, address to, uint256 value) returns (bool);
  function approve(address spender, uint256 value) returns (bool);
  event Approval(address indexed owner, address indexed spender, uint256 value);
}

/**
 * @title SafeMath
 * @dev Math operations with safety checks that throw on error
 */
library SafeMath {

  function mul(uint256 a, uint256 b) internal constant returns (uint256) {
    uint256 c = a * b;
    assert(a == 0 || c / a == b);
    return c;
  }

  function div(uint256 a, uint256 b) internal constant returns (uint256) {
    // assert(b > 0); // Solidity automatically throws when dividing by 0
    uint256 c = a / b;
    // assert(a == b * c + a % b); // There is no case in which this doesn't hold
    return c;
  }

  function sub(uint256 a, uint256 b) internal constant returns (uint256) {
    assert(b <= a);
    return a - b;
  }

  function add(uint256 a, uint256 b) internal constant returns (uint256) {
    uint256 c = a + b;
    assert(c >= a);
    return c;
  }

}

/**
 * @title Basic token
 * @dev Basic version of StandardToken, with no allowances. 
 */
contract BasicToken is ERC20Basic {

  using SafeMath for uint256;

  mapping(address => uint256) balances;

  /**
  * @dev transfer token for a specified address
  * @param _to The address to transfer to.
  * @param _value The amount to be transferred.
  */
  function transfer(address _to, uint256 _value) returns (bool) {
    balances[msg.sender] = balances[msg.sender].sub(_value);
    balances[_to] = balances[_to].add(_value);
    Transfer(msg.sender, _to, _value);
    return true;
  }

  /**
  * @dev Gets the balance of the specified address.
  * @param _owner The address to query the the balance of. 
  * @return An uint256 representing the amount owned by the passed address.
  */
  function balanceOf(address _owner) constant returns (uint256 balance) {
    return balances[_owner];
  }

}

/**
 * @title Standard ERC20 token
 *
 * @dev Implementation of the basic standard token.
 * @dev https://github.com/ethereum/EIPs/issues/20
 * @dev Based on code by FirstBlood: https://github.com/Firstbloodio/token/blob/master/smart_contract/FirstBloodToken.sol
 */
contract StandardToken is ERC20, BasicToken {

  mapping (address => mapping (address => uint256)) allowed;

  /**
   * @dev Transfer tokens from one address to another
   * @param _from address The address which you want to send tokens from
   * @param _to address The address which you want to transfer to
   * @param _value uint256 the amout of tokens to be transfered
   */
  function transferFrom(address _from, address _to, uint256 _value) returns (bool) {
    var _allowance = allowed[_from][msg.sender];

    // Check is not needed because sub(_allowance, _value) will already throw if this condition is not met
    // require (_value <= _allowance);

    balances[_to] = balances[_to].add(_value);
    balances[_from] = balances[_from].sub(_value);
    allowed[_from][msg.sender] = _allowance.sub(_value);
    Transfer(_from, _to, _value);
    return true;
  }

  /**
   * @dev Aprove the passed address to spend the specified amount of tokens on behalf of msg.sender.
   * @param _spender The address which will spend the funds.
   * @param _value The amount of tokens to be spent.
   */
  function approve(address _spender, uint256 _value) returns (bool) {

    // To change the approve amount you first have to reduce the addresses`
    //  allowance to zero by calling `approve(_spender, 0)` if it is not
    //  already 0 to mitigate the race condition described here:
    //  https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
    require((_value == 0) || (allowed[msg.sender][_spender] == 0));

    allowed[msg.sender][_spender] = _value;
    Approval(msg.sender, _spender, _value);
    return true;
  }

  /**
   * @dev Function to check the amount of tokens that an owner allowed to a spender.
   * @param _owner address The address which owns the funds.
   * @param _spender address The address which will spend the funds.
   * @return A uint256 specifing the amount of tokens still available for the spender.
   */
  function allowance(address _owner, address _spender) constant returns (uint256 remaining) {
    return allowed[_owner][_spender];
  }

}

/**
 * @title Ownable
 * @dev The Ownable contract has an owner address, and provides basic authorization control
 * functions, this simplifies the implementation of "user permissions".
 */
contract Ownable {

  address public owner;

  /**
   * @dev The Ownable constructor sets the original `owner` of the contract to the sender
   * account.
   */
  function Ownable() {
    owner = msg.sender;
  }

  /**
   * @dev Throws if called by any account other than the owner.
   */
  modifier onlyOwner() {
    require(msg.sender == owner);
    _;
  }

  /**
   * @dev Allows the current owner to transfer control of the contract to a newOwner.
   * @param newOwner The address to transfer ownership to.
   */
  function transferOwnership(address newOwner) onlyOwner {
    require(newOwner != address(0));      
    owner = newOwner;
  }

}

/**
 * @title Mintable token
 * @dev Simple ERC20 Token example, with mintable token creation
 * @dev Issue: * https://github.com/OpenZeppelin/zeppelin-solidity/issues/120
 * Based on code by TokenMarketNet: https://github.com/TokenMarketNet/ico/blob/master/contracts/MintableToken.sol
 */

contract MintableToken is StandardToken, Ownable {

  event Mint(address indexed to, uint256 amount);

  event MintFinished();

  bool public mintingFinished = false;

  modifier canMint() {
    require(!mintingFinished);
    _;
  }

  /**
   * @dev Function to mint tokens
   * @param _to The address that will recieve the minted tokens.
   * @param _amount The amount of tokens to mint.
   * @return A boolean that indicates if the operation was successful.
   */
  function mint(address _to, uint256 _amount) onlyOwner canMint returns (bool) {
    totalSupply = totalSupply.add(_amount);
    balances[_to] = balances[_to].add(_amount);
    Mint(_to, _amount);
    return true;
  }

  /**
   * @dev Function to stop minting new tokens.
   * @return True if the operation was successful.
   */
  function finishMinting() onlyOwner returns (bool) {
    mintingFinished = true;
    MintFinished();
    return true;
  }

}

contract SimpleTokenCoin is MintableToken {

    string public constant name = "Simple Coint Token";

    string public constant symbol = "SCT";

    uint32 public constant decimals = 18;

}


contract Crowdsale is Ownable {

    using SafeMath for uint;

    address multisig;

    uint restrictedPercent;

    address restricted;

    SimpleTokenCoin public token = new SimpleTokenCoin();

    uint start;

    uint period;

    uint hardcap;

    uint rate;

    function Crowdsale() {
        multisig = 0xEA15Adb66DC92a4BbCcC8Bf32fd25E2e86a2A770;
        restricted = 0xb3eD172CC64839FB0C0Aa06aa129f402e994e7De;
        restrictedPercent = 40;
        rate = 100000000000000000000;
        start = 1500379200;
        period = 28;
        hardcap = 10000000000000000000000;
    }

    modifier saleIsOn() {
        require(now > start && now < start + period * 1 days);
        _;
    }

    modifier isUnderHardCap() {
        require(multisig.balance <= hardcap);
        _;
    }

    function finishMinting() public onlyOwner {
        uint issuedTokenSupply = token.totalSupply();
        uint restrictedTokens = issuedTokenSupply.mul(restrictedPercent).div(100 - restrictedPercent);
        token.mint(restricted, restrictedTokens);
        token.finishMinting();
    }

    function createTokens() isUnderHardCap saleIsOn payable {
        multisig.transfer(msg.value);
        uint tokens = rate.mul(msg.value).div(1 ether);
        token.mint(msg.sender, tokens);
    }

    function() external payable {
        createTokens();
    }

}

На цьому уроці ми навчились випускати додаткові токени по закінченню ІСО. А також встановили межу збору коштів. Також ми зробили ще кілька вдосконалень і тепер наш контракт виглядає як справжній!

Йому не вистачає лише одного – бонусів для інвесторів, які вклали кошти першими. Тому у наступному уроці ми продовжимо вивчати, як написати смарт-контракт ІСО на ефірі та займемося бонусами!

[Продовження читати тут]http://ethereum.net.ua/discussion/43/smart-kontrakt-na-solidity-chastina-9?new=1 "Продовження читати тут").

Войдите или Зарегистрируйтесь чтобы комментировать.