Привет, незнакомец!

Похоже, вы здесь новенький. Чтобы принять участие, нажмите одну из кнопок ниже!

Смарт-контракт на Solidity: Частина 11 — ICO, refund — поверненя коштів по softcap

отредактировано December 2017 Раздел: Смарт Контракты

Серія уроків була взята з сайту inaword.ru

У попередній статті ми познайомилися з видами емісій і навчилися верифікувати контракт в etherscan. Тепер наше завдання створити механізм повернення коштів, тим самим підвищивши довіру інвесторів.

У деяких ICO для реалізації проекту необхідна якась мінімальна сума. Так званий softcap. Якщо засновники її не збирають, то проект неможливо реалізувати.

Навіщо потрібен механізм повернення коштів по softcap?

  1. Якщо під час ICO softcap не була досягнута, то виходить що і гроші і проект не будуть виконані. В цьому випадку, якщо ви не повернете кошти, то інвестори можуть подумати, що ви шахрай.
  2. Наявність повернення коштів підвищує довіру інвесторів.

Коли повернення по softcap не потрібне?

  1. Якщо ваш проект не має мінімальної суми для реалізації. Наприклад, якщо у вас проект по інвестиціям у валюту, то тут мінімальна сума не потрібна. У будь-якому випадку, можна інвестувати будь-яку суму.
  2. Коли ви чітко прописуєте в WhitePaper, що у разі недосягнення softcap інвестиції не повертаються (це може бути виправдано як покриття витрат на запуск ICO).
  3. Якщо ви досить впевнені в тому, що зберете softcap. Така впевненість може ґрунтуватися на результатах збору під час presale.

Як зробити механізм повернення коштів?

Механізм повернення коштів може бути реалізовано, як на presale так і на ICO. Працює він досить просто. Під час ICO кошти інвесторів перераховуються не на спеціальний рахунок-контракт. З цього рахунку засновники не можуть вивести гроші до закінчення ICO. По закінченню можна перевірити - чи досягнуто softcap. Якщо не досягнуто, то кошти залишаються на спеціальному рахунку і інвестори можуть повернути собі кошти шляхом виклику спеціальної функції повернення. Зазвичай її називають refund. Якщо ж softcap був досягнутий, то кошти з спец-рахунку переводяться на рахунок засновників.

Давайте приступимо до нашої реалізації. За основу ми візьмемо код 9-го уроку.

Для простоти, кошти інвесторів у нас будуть збираються на рахунку контракту розпродажі.

Нижня межа зборів softcap у нас буде зберігається в змінної sotfcap.

uint softcap;

Якщо softcap не досягнутий і ICO закінчено, то користувачі зможуть вивести кошти за допомогою функції refund.

function refund() {
  require(this.balance < softcap && now > start + period * 1 days);
  ...
}

Спочатку йде перевірка, що баланс контракту більший від softcap і що ICO вже закінчилося. Але як же нам повертати кошти інвесторів, якщо ми не знаємо скільки кожен інвестував?

Для цього під час інвестування ми будемо зберігати адресу інвестора і скільки він інвестував в мепі:

mapping(address => uint) public balances;

Поправимо функцію продажі токена, щоб вона зберігала суму інвестора. Додамо рядок в кінець. І приберемо перерахування коштів на multisig. Тепер кошти залишаються на контракті розпродажі.

function createTokens() isUnderHardCap saleIsOn payable {
  ...
  balances[msg.sender] = balances[msg.sender].add(msg.value);
}

Тепер ми нарешті можемо дописати нашу функцію повернення коштів.

function refund() {
  require(this.balance < softcap && now > start + period * 1 days);
  uint value = balances[msg.sender];
  balances[msg.sender] = 0;
  msg.sender.transfer(value);
}

В кінці ICO при виклику finishMinting ми будемо визначати чи досягнуто softcap. І якщо досягнуто, то будемо переводити всі кошти з акаунта контракту на гаманець засновників. Також всі інші дії з цієї функції будуть виконуватися тільки в разі досягнення softcap. Інакше вони не матимуть сенсу.

function finishMinting() public onlyOwner {
      if(this.balance > softcap) {
        multisig.transfer(this.balance);
        uint issuedTokenSupply = token.totalSupply();
    uint restrictedTokens = issuedTokenSupply.mul(restrictedPercent).div(100 - restrictedPercent);
        token.mint(restricted, restrictedTokens);
        token.finishMinting();
      }
}

На цьому наші доопрацювання закінчилися, ось весь код.

pragma solidity ^0.4.15;

/**
 * @title ERC20Basic
 * @dev Simpler version of ERC20 interface
 * @dev see https://github.com/ethereum/EIPs/issues/179
 */
contract ERC20Basic {
  uint256 public totalSupply;
  function balanceOf(address who) constant returns (uint256);
  function transfer(address to, uint256 value) returns (bool);
  event Transfer(address indexed from, address indexed to, uint256 value);
}

/**
 * @title ERC20 interface
 * @dev see https://github.com/ethereum/EIPs/issues/20
 */
contract ERC20 is ERC20Basic {
  function allowance(address owner, address spender) constant returns (uint256);
  function transferFrom(address from, address to, uint256 value) returns (bool);
  function approve(address spender, uint256 value) returns (bool);
  event Approval(address indexed owner, address indexed spender, uint256 value);
}

/**
 * @title SafeMath
 * @dev Math operations with safety checks that throw on error
 */
library SafeMath {

  function mul(uint256 a, uint256 b) internal constant returns (uint256) {
    uint256 c = a * b;
    assert(a == 0 || c / a == b);
    return c;
  }

  function div(uint256 a, uint256 b) internal constant returns (uint256) {
    // assert(b > 0); // Solidity automatically throws when dividing by 0
    uint256 c = a / b;
    // assert(a == b * c + a % b); // There is no case in which this doesn't hold
    return c;
  }

  function sub(uint256 a, uint256 b) internal constant returns (uint256) {
    assert(b <= a);
    return a - b;
  }

  function add(uint256 a, uint256 b) internal constant returns (uint256) {
    uint256 c = a + b;
    assert(c >= a);
    return c;
  }

}

/**
 * @title Basic token
 * @dev Basic version of StandardToken, with no allowances. 
 */
contract BasicToken is ERC20Basic {

  using SafeMath for uint256;

  mapping(address => uint256) balances;

  /**
  * @dev transfer token for a specified address
  * @param _to The address to transfer to.
  * @param _value The amount to be transferred.
  */
  function transfer(address _to, uint256 _value) returns (bool) {
    balances[msg.sender] = balances[msg.sender].sub(_value);
    balances[_to] = balances[_to].add(_value);
    Transfer(msg.sender, _to, _value);
    return true;
  }

  /**
  * @dev Gets the balance of the specified address.
  * @param _owner The address to query the the balance of. 
  * @return An uint256 representing the amount owned by the passed address.
  */
  function balanceOf(address _owner) constant returns (uint256 balance) {
    return balances[_owner];
  }

}

/**
 * @title Standard ERC20 token
 *
 * @dev Implementation of the basic standard token.
 * @dev https://github.com/ethereum/EIPs/issues/20
 * @dev Based on code by FirstBlood: https://github.com/Firstbloodio/token/blob/master/smart_contract/FirstBloodToken.sol
 */
contract StandardToken is ERC20, BasicToken {

  mapping (address => mapping (address => uint256)) allowed;

  /**
   * @dev Transfer tokens from one address to another
   * @param _from address The address which you want to send tokens from
   * @param _to address The address which you want to transfer to
   * @param _value uint256 the amout of tokens to be transfered
   */
  function transferFrom(address _from, address _to, uint256 _value) returns (bool) {
    var _allowance = allowed[_from][msg.sender];

    // Check is not needed because sub(_allowance, _value) will already throw if this condition is not met
    // require (_value <= _allowance);

    balances[_to] = balances[_to].add(_value);
    balances[_from] = balances[_from].sub(_value);
    allowed[_from][msg.sender] = _allowance.sub(_value);
    Transfer(_from, _to, _value);
    return true;
  }

  /**
   * @dev Aprove the passed address to spend the specified amount of tokens on behalf of msg.sender.
   * @param _spender The address which will spend the funds.
   * @param _value The amount of tokens to be spent.
   */
  function approve(address _spender, uint256 _value) returns (bool) {

    // To change the approve amount you first have to reduce the addresses`
    //  allowance to zero by calling `approve(_spender, 0)` if it is not
    //  already 0 to mitigate the race condition described here:
    //  https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
    require((_value == 0) || (allowed[msg.sender][_spender] == 0));

    allowed[msg.sender][_spender] = _value;
    Approval(msg.sender, _spender, _value);
    return true;
  }

  /**
   * @dev Function to check the amount of tokens that an owner allowed to a spender.
   * @param _owner address The address which owns the funds.
   * @param _spender address The address which will spend the funds.
   * @return A uint256 specifing the amount of tokens still available for the spender.
   */
  function allowance(address _owner, address _spender) constant returns (uint256 remaining) {
    return allowed[_owner][_spender];
  }

}

/**
 * @title Ownable
 * @dev The Ownable contract has an owner address, and provides basic authorization control
 * functions, this simplifies the implementation of "user permissions".
 */
contract Ownable {

  address public owner;

  /**
   * @dev The Ownable constructor sets the original `owner` of the contract to the sender
   * account.
   */
  function Ownable() {
    owner = msg.sender;
  }

  /**
   * @dev Throws if called by any account other than the owner.
   */
  modifier onlyOwner() {
    require(msg.sender == owner);
    _;
  }

  /**
   * @dev Allows the current owner to transfer control of the contract to a newOwner.
   * @param newOwner The address to transfer ownership to.
   */
  function transferOwnership(address newOwner) onlyOwner {
    require(newOwner != address(0));      
    owner = newOwner;
  }

}

/**
 * @title Mintable token
 * @dev Simple ERC20 Token example, with mintable token creation
 * @dev Issue: * https://github.com/OpenZeppelin/zeppelin-solidity/issues/120
 * Based on code by TokenMarketNet: https://github.com/TokenMarketNet/ico/blob/master/contracts/MintableToken.sol
 */

contract MintableToken is StandardToken, Ownable {

  event Mint(address indexed to, uint256 amount);

  event MintFinished();

  bool public mintingFinished = false;

  modifier canMint() {
    require(!mintingFinished);
    _;
  }

  /**
   * @dev Function to mint tokens
   * @param _to The address that will recieve the minted tokens.
   * @param _amount The amount of tokens to mint.
   * @return A boolean that indicates if the operation was successful.
   */
  function mint(address _to, uint256 _amount) onlyOwner canMint returns (bool) {
    totalSupply = totalSupply.add(_amount);
    balances[_to] = balances[_to].add(_amount);
    Mint(_to, _amount);
    return true;
  }

  /**
   * @dev Function to stop minting new tokens.
   * @return True if the operation was successful.
   */
  function finishMinting() onlyOwner returns (bool) {
    mintingFinished = true;
    MintFinished();
    return true;
  }

}

contract SimpleTokenCoin is MintableToken {

    string public constant name = "Simple Coint Token";

    string public constant symbol = "SCT";

    uint32 public constant decimals = 18;

}


contract Crowdsale is Ownable {

    using SafeMath for uint;

    address public multisig;

    uint public restrictedPercent;

    address public restricted;

    SimpleTokenCoin public token = new SimpleTokenCoin();

    uint public start;

    uint public period;

    uint public hardcap;

    uint public rate;

    uint public softcap;

    mapping(address => uint) public balances;

    function Crowdsale() {
      multisig = 0xEA15Adb66DC92a4BbCcC8Bf32fd25E2e86a2A770;
      restricted = 0xb3eD172CC64839FB0C0Aa06aa129f402e994e7De;
      restrictedPercent = 40;
      rate = 100000000000000000000;
      start = 1500379200;
      period = 28;
      hardcap = 10000000000000000000000;
      softcap = 1000000000000000000000;
    }

    modifier saleIsOn() {
      require(now > start && now < start + period * 1 days);
      _;
    }

    modifier isUnderHardCap() {
      require(multisig.balance <= hardcap);
      _;
    }

    function refund() {
      require(this.balance < softcap && now > start + period * 1 days);
      uint value = balances[msg.sender]; 
      balances[msg.sender] = 0; 
      msg.sender.transfer(value); 
    }

    function finishMinting() public onlyOwner {
      if(this.balance > softcap) {
        multisig.transfer(this.balance);
        uint issuedTokenSupply = token.totalSupply();
        uint restrictedTokens = issuedTokenSupply.mul(restrictedPercent).div(100 - restrictedPercent);
        token.mint(restricted, restrictedTokens);
        token.finishMinting();
      }
    }

   function createTokens() isUnderHardCap saleIsOn payable {
      uint tokens = rate.mul(msg.value).div(1 ether);
      uint bonusTokens = 0;
      if(now < start + (period * 1 days).div(4)) {
        bonusTokens = tokens.div(4);
      } else if(now >= start + (period * 1 days).div(4) && now < start + (period * 1 days).div(4).mul(2)) {
        bonusTokens = tokens.div(10);
      } else if(now >= start + (period * 1 days).div(4).mul(2) && now < start + (period * 1 days).div(4).mul(3)) {
        bonusTokens = tokens.div(20);
      }
      tokens += bonusTokens;
      token.mint(msg.sender, tokens);
      balances[msg.sender] = balances[msg.sender].add(msg.value);
    }

    function() external payable {
      createTokens();
    }

}

Тепер наші інвестори можуть бути впевнені, що зможуть забрати кошти, якщо вкладень буде недостатньо для реалізації проекту.

Ви можете запитати - чому не можна автоматично повернути кошти? Чому саме сам інвестор повинен викликати refund, щоб повернути? Справа в тому що на кожну інструкцію витрачається газ. Уявіть що у нас кілька тисяч інвесторів. У цьому випадку витрати на розсилку різко зростуть. Саме тому ми не робимо автоматичне повернення коштів в finishMinting.

Як вже знаєте завжди краще використовувати готове рішення. Refund - це добре відомий механізм і він має свою реалізацію в OpenZepplein. Вона набагато складніше ніж та що описана в цій статті, але принцип той-же. Ця реалізація складається з двох контрактів.

  1. RefundableCrowdsale — контракт для проведення ICO з можливістю повернення коштів.
  2. RefunValut — спеціальний контракт-рахунок для зберігання коштів до закінчення ICO.

Розбір шаблону OpenZepplin залишається для самостійної підготовки.

Продовження читати тут.

Войдите или Зарегистрируйтесь чтобы комментировать.